From df4c115717bd4759c1f173442dd59623231acc0a Mon Sep 17 00:00:00 2001
From: Gaetan Nadon <memsize@videotron.ca>
Date: Sun, 6 Sep 2009 15:01:38 -0400
Subject: [PATCH] Install ax_define_dir.m4 to replace modules private copy #23750

http://www.nongnu.org/autoconf-archive/ax_define_dir.html
Renamed from AC_DEFINE_DIR to AX_DEFINE_DIR, same code.
---
 Makefile.am      |    2 +-
 ax_define_dir.m4 |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+), 1 deletions(-)
 create mode 100644 ax_define_dir.m4

diff --git a/Makefile.am b/Makefile.am
index 265bfd7..bc9e1ff 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -20,7 +20,7 @@
 #  CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
 
 aclocaldir = $(datadir)/aclocal
-aclocal_DATA = xorg-macros.m4
+aclocal_DATA = xorg-macros.m4 ax_define_dir.m4
 
 # Previous versions used to install xorgversion.m4, now integrated
 # into xorg-macros.m4.  Explicitly remove that old file in order not
diff --git a/ax_define_dir.m4 b/ax_define_dir.m4
new file mode 100644
index 0000000..b7501e8
--- /dev/null
+++ b/ax_define_dir.m4
@@ -0,0 +1,46 @@
+# ===========================================================================
+#          http://www.nongnu.org/autoconf-archive/ax_define_dir.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
+#
+# DESCRIPTION
+#
+#   This macro sets VARNAME to the expansion of the DIR variable, taking
+#   care of fixing up ${prefix} and such.
+#
+#   VARNAME is then offered as both an output variable and a C preprocessor
+#   symbol.
+#
+#   Example:
+#
+#      AX_DEFINE_DIR([DATADIR], [datadir], [Where data are placed to.])
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Stepan Kasal <kasal@ucw.cz>
+#   Copyright (c) 2008 Andreas Schwab <schwab@suse.de>
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2008 Alexandre Oliva
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved.
+
+AU_ALIAS([AC_DEFINE_DIR], [AX_DEFINE_DIR])
+AC_DEFUN([AX_DEFINE_DIR], [
+  prefix_NONE=
+  exec_prefix_NONE=
+  test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
+  test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
+dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
+dnl refers to ${prefix}.  Thus we have to use `eval' twice.
+  eval ax_define_dir="\"[$]$2\""
+  eval ax_define_dir="\"$ax_define_dir\""
+  AC_SUBST($1, "$ax_define_dir")
+  AC_DEFINE_UNQUOTED($1, "$ax_define_dir", [$3])
+  test "$prefix_NONE" && prefix=NONE
+  test "$exec_prefix_NONE" && exec_prefix=NONE
+])
-- 
1.6.0.4